
    WardrikPolicy

Rules, judges and budgets that decide what an agent may do and spend.
Install
def deps do
  [
    {:wardrik_policy, "~> 0.1.0-rc.1"}
  ]
end
Decide a call
policy =
  WardrikPolicy.new!(
    allow: ["web_search", "write_file(notes/*)"],
    ask: %{"books/create_bill(amount >= 1000)" => "A bill this size needs a person."},
    deny: ["shell/*"]
  )

WardrikPolicy.decide(policy, "books__create_bill", arguments: %{"amount" => 9400})
#=> {:ask, "A bill this size needs a person."}
The rules live outside the prompt, so nothing the model reads can widen them.
	The model asks for	The rule that names it	What happens
	web_search	allow: ["web_search"]	Runs
	write_file {"path": "notes/today.md"}	allow: ["write_file(notes/*)"]	Runs
	books/create_bill {"amount": 9400}	ask: ["books/create_bill(amount >= 1000)"]	Waits for a person
	shell/exec {"command": "curl … | sh"}	deny: ["shell/*"]	Refused

The strictest rule wins: deny, then ask, then allow. A call no rule names follows default:, which
is :allow unless set.
To see which rule decided, call WardrikPolicy.explain/3. It returns a WardrikPolicy.Decision.
Rules
"web_search"                         # a tool
"github/*"                           # every tool from the github MCP server
"write_file(notes/*)"                # what the call acts on
"books/create_bill(amount >= 1000)"  # an argument
"email/send(to != *@acme.com)"       # a comma means all conditions must hold
	An MCP tool named github__create_issue also matches as github/create_issue.
	Pass what a call acts on as decide/3's resources:.
	Conditions use =, !=, >, >=, < and <=.

Decide what no rule names
A tool describes itself with annotations, like read_only: true. The default can depend on them:
policy =
  WardrikPolicy.new!(
    allow: ["github/create_issue"],
    default: [destructive: :deny, read_only: :allow, else: :ask]
  )

WardrikPolicy.decide(policy, "github__list_issues", annotations: %{read_only: true})
#=> :allow
WardrikPolicy.decide(policy, "github__close_issue")
#=> {:ask, "github/close_issue needs your approval."}
	github/create_issue runs, because a rule names it.
	A tool marked destructive is refused.
	When a tool has several annotations, the strictest wins.
	else covers a tool with none of them. It is :allow unless set.

A default applies to its own policy only. An agent's own allow can't lift its org's else: :ask.
Policy files
WardrikPolicy.decode/2 reads a policy from a map with string keys, such as one parsed from YAML.
It reads budget and judge too.
allow: [web_search]
deny: ["email/send(to != *@acme.com)"]
default: ask
budget:
  usd: 5.00
  per: day
After content from outside
A run that has read content from outside, such as a web page or an issue a stranger filed, may have
been told what to call. Once a run has the "outside" label, a call to a gated tool asks a person,
even if a rule allows it. See WardrikCore.Context.labels/1.
policy =
  WardrikPolicy.new!(
    allow: ["linear/*"],
    allow_after: %{"outside" => ["github/add_labels"]}
  )

WardrikPolicy.decide(policy, "linear__create_issue",
  annotations: %{gated: true},
  labels: ["outside"]
)
#=> {:ask, "linear/create_issue is allowed, but this run has read content from outside, which may be what asked for it."}
	A tool is gated when its annotations include gated: true.
	allow_after keeps a call allowed after that label. Use it for tools a stranger can't misuse.
	An ask or deny still wins over allow_after.
	Any label allow_after names holds gated calls the same way "outside" does.
	A judge's allow is ignored once the run has read content from outside.

Judge a call
Some decisions depend on what a call means, not its name. A judge asks a model yes-or-no
questions about each call, and decides by the probability of yes:
policy =
  WardrikPolicy.new!(
    judge: [
      questions: [
        [
          question: "Does this call send money outside the company?",
          tools: ["books/*"],
          ask: 0.5,
          deny: 0.9
        ]
      ]
    ]
  )

WardrikPolicy.decide(policy, "books__pay_bill",
  arguments: %{"amount" => 1200},
  evaluate: fn _model, _call, _questions -> {:ok, [0.72], %{usd: 0.0001}} end
)
#=> {:ask, "Judged 72% likely: Does this call send money outside the company?"}
A judge takes a model, "typesafe:jev-latest" unless set, and its questions. Each question
takes:
	Key	Takes	Unless set
	question	what the model is asked about the call	required
	tools	tool names it applies to, as ["books/*"], without arguments	every tool
	deny	refuse the call at or above this probability	
	ask	ask a person at or above this probability	
	allow	allow the call below this probability	
	message	the prompt or refusal to show in place of the question	

A question needs at least one of deny, ask and allow, each from 0 to 1.
evaluate: is the function that asks the model. It returns each question's probability of yes and
what the request used. The decision carries that as measurements.
	A deny beats an ask, and an ask beats an allow, across questions and rules.
	A judge's allow never overrides a rule's ask or deny.
	If the model can't answer, the call asks a person, as long as some question could ask or deny.

The call's arguments may be written to fool the judge. Keep exact checks in rules, and test the
thresholds on real calls before trusting the judge's allow.
Cap what an agent spends
policy = WardrikPolicy.new!(budget: [usd: 5.00, per: :day])

WardrikPolicy.Budget.check(policy.budget, %{usd: 5.02})
#=> {:ask, "This agent has spent $5.02 of $5.00 today. Approve to allow $5.00 more."}
Check the budget before each model call, with what the earlier calls spent. The call that crosses
the limit still runs. The next one asks. Approving allows another grant's worth.
	Key	Takes	Unless set
	usd	a limit in US dollars	no dollar limit
	tokens	a limit in tokens, input and output together	no token limit
	per	:turn, :day, :week, :month or :total	:day
	timezone	where a day, week or month begins, as "Europe/Berlin"	"Etc/UTC"
	grant	how much more an approval allows, as [usd: 2.00]	another limit
	price	dollars per million tokens, as [input: 0.60, output: 2.20]	the cost the model reports
	on_exhausted	:ask a person, or :deny	:ask

Weeks begin on Monday.
WardrikPolicy.Middleware keeps track of spending for you. To do it yourself:
	Reset what was spent when WardrikPolicy.Budget.period/2 returns a new period.
	Pass it through WardrikPolicy.Budget.grant/2 when a person approves.

Several policies
Pass a list to decide/3 to hold an agent to its org's policy and its own. The strictest decision
wins, so an agent's own policy can add caution but never remove it:
# acme.yaml, the org's
deny: [shell/*]
# books.yaml, the agent's
allow: [shell/*, books/*]
shell/exec is refused, even though the agent's policy allows it. Each policy's budget is counted
separately.
With WardrikCore
WardrikPolicy.Middleware is a WardrikCore middleware. It
checks each model call against the budgets, and decides each tool call by the rules and judges:
WardrikCore.start_agent(
  agent_id: "books",
  model: "anthropic:claude-haiku-4-5",
  middleware: [{WardrikPolicy.Middleware, policy}]
)
	What the agent spent survives restarts.
	A judge asks its model with WardrikCore.evaluate/4. That cost counts against the budget too.
	A dollar budget needs the model's price. If the model reports no dollar cost, as with a
subscription, model calls are refused after the first one. Set the budget's price, or cap
tokens instead.

A call that asks parks on a WardrikPolicy.Ask. Answer it with WardrikCore.resume/3, keyed by
the tool call's id, or "model" for a model call:
WardrikCore.resume(agent, %{"call_123" => :approve}, %{by: "maria"})
WardrikCore.resume(agent, %{"call_123" => {:approve, "Checked with finance."}})
WardrikCore.resume(agent, %{"model" => {:deny, "Over budget for today."}})
A note reaches the model beside the call's result. A reason reaches it as the call's error. The
metadata records who answered.
The middleware reads each tool's annotations from WardrikCore.Tool. The resources annotation
returns what a call acts on, from its arguments:
WardrikCore.Tool.new!(
  name: "write_file",
  description: "Write a file.",
  schema: [path: [type: :string, required: true], text: [type: :string]],
  run: fn %{path: path, text: text}, _context -> {:ok, File.write!(path, text)} end,
  annotations: [resources: fn args -> [args["path"]] end]
)
Every decision and answer is a telemetry event, and each decision is set on its step's span. That
is the record of what the agent was allowed to do, and who said so. See WardrikPolicy.Middleware.
License
Apache-2.0


  

    Changelog

0.1.0-rc.1 (2026-10-30)
	Rules that allow, ask about or deny each tool call, by tool, by the resources a call acts on, and
by its arguments. The strictest rule wins, across several policies too.
	A default that can turn on a tool's annotations, like [read_only: :allow, else: :ask].
	Policies built in Elixir with new!/2, read from YAML or JSON with decode/2, and written back
with to_json/1.
	Budgets in dollars, tokens or both, per turn, day, week, month or for good, in any time zone.
	Judges that ask a model yes-or-no questions about a call, and decide by the probability of yes.
	Gated calls wait for a person once the run has read content from outside, unless allow_after
allows them after that label.
	WardrikPolicy.Middleware, which holds a WardrikCore agent to its policies, parks calls that ask,
and reports every decision as a telemetry event and on its step's span.
	The protocol's wardrik.tool_call.denied and wardrik.interrupt.resolved events, and asks that
name their interrupt, message and the run's labels.

Decides each tool call an agent makes: run it, ask a person first, or refuse it.
iex> policy =
...>   WardrikPolicy.new!(
...>     allow: ["web_search", "write_file(notes/*)"],
...>     ask: %{"books/create_bill(amount >= 1000)" => "A bill this size needs a person."},
...>     deny: ["shell/*"]
...>   )
iex> WardrikPolicy.decide(policy, "web_search")
:allow
iex> WardrikPolicy.decide(policy, "books__create_bill", arguments: %{"amount" => 9400})
{:ask, "A bill this size needs a person."}
iex> WardrikPolicy.decide(policy, "shell__exec")
{:deny, "shell/exec is not allowed for this agent."}
iex> WardrikPolicy.explain(policy, "shell__exec")
%WardrikPolicy.Decision{
  effect: :deny,
  message: "shell/exec is not allowed for this agent.",
  rule: "shell/*",
  cause: :rule
}
The strictest rule wins: deny, then ask, then allow.
Rules
	:allow - tool patterns that run.
	:ask - tool patterns that wait for a person. A map of pattern to message sets the prompt.
	:deny - tool patterns that are refused. A map of pattern to message sets the refusal.
	:allow_after - a map of label to patterns that stay allowed after the run reads content
with that label. See "Content from outside" below.
	:default - what a call no rule names gets: :allow, :ask, :deny, or a map by
annotation. :allow unless set.
	:budget - caps what the agent spends on model calls. See WardrikPolicy.Budget.
	:judge - asks a model about each call. See WardrikPolicy.Judge.

A pattern names a tool, what the call acts on, or its arguments:
"web_search"                            # one tool
"github/*"                              # every tool from the github MCP server
"write_file(notes/*)"                   # what the call acts on, given as :resources
"books/create_bill(amount >= 1000)"     # an argument; =, !=, >, >=, < and <=
"email/send(to != *@acme.com)"          # a comma means all conditions must hold
An MCP tool named github__create_issue also matches as github/create_issue.
Defaults by annotation
A call no rule names follows :default. The default can depend on the tool's annotations:
iex> policy =
...>   WardrikPolicy.new!(
...>     allow: ["write_file(notes/*)"],
...>     default: [read_only: :allow, else: :ask]
...>   )
iex> WardrikPolicy.decide(policy, "write_file", resources: ["notes/today.md"])
:allow
iex> WardrikPolicy.decide(policy, "write_file", resources: ["secrets/key"])
{:ask, "write_file needs your approval."}
iex> WardrikPolicy.decide(policy, "read_file", annotations: %{read_only: true})
:allow
When a tool has several annotations, the strictest wins. else covers a tool with none of them,
and is :allow unless set.
Policy files
Parse the YAML into a map, then call decode/2:
iex> {:ok, policy} =
...>   WardrikPolicy.decode(%{"deny" => ["email/send(to != *@acme.com)"], "default" => "ask"})
iex> WardrikPolicy.decide(policy, "email__send", arguments: %{"to" => "x@evil.example"})
{:deny, "email/send is not allowed for this agent."}
iex> WardrikPolicy.decide(policy, "web_search")
{:ask, "web_search needs your approval."}
to_json/1 writes a policy back as that map.
Content from outside
A run that has read content from outside, such as a web page, may have been told what to call.
So once a run carries the "outside" label, a call to a gated tool asks a person, even if a rule
allows it. Pass the run's labels as :labels. allow_after keeps a call allowed for tools a
stranger can't misuse:
iex> policy =
...>   WardrikPolicy.new!(
...>     allow: ["linear/*"],
...>     allow_after: %{"outside" => ["github/add_labels"]}
...>   )
iex> gated = %{gated: true}
iex> WardrikPolicy.decide(policy, "linear__create_issue", annotations: gated, labels: ["outside"])
{:ask, "linear/create_issue is allowed, but this run has read content from outside, which may be what asked for it."}
iex> WardrikPolicy.decide(policy, "github__add_labels", annotations: gated, labels: ["outside"])
:allow
A tool is gated when its annotations include gated: true. Any label that allow_after names
holds gated calls the same way "outside" does. Other labels hold nothing.

        Decides a call to the tool name. Returns :allow, {:ask, prompt} or {:deny, message}.

        Reads a policy from a map with string keys, such as one parsed from YAML.

        Decides a call like decide/3, but returns a WardrikPolicy.Decision that says what decided.

        Builds a policy from a keyword list or map. See the module docs for the keys.

        Encodes a policy as the map decode/2 reads, such as to store it as JSON.

          @type decision() :: :allow | {:ask, String.t()} | {:deny, String.t()}

          @type effect() :: :allow | :ask | :deny

          @type t() :: %WardrikPolicy{
  budget: WardrikPolicy.Budget.t() | nil,
  by_annotation: %{required(String.t()) => effect()},
  default: effect(),
  judge: WardrikPolicy.Judge.t() | nil,
  name: String.t() | nil,
  rules: list()
}

          @spec decide(t() | [t()], String.t(), keyword()) :: decision()


      


Decides a call to the tool name. Returns :allow, {:ask, prompt} or {:deny, message}.
Given a list of policies, the strictest decision wins.
Options
	:arguments - the call's arguments, as a map with string keys. %{} unless set.
	:resources - what the call acts on, such as file paths. [] unless set.
	:annotations - the tool's annotations, as %{read_only: true}. %{} unless set.
	:labels - labels for what the run has read, as ["outside"]. [] unless set.
	:evaluate - asks a judge's model. See WardrikPolicy.Judge.evaluate/0.

          @spec decode(map(), keyword()) :: {:ok, t()} | {:error, String.t()}


      


Reads a policy from a map with string keys, such as one parsed from YAML.
Returns {:error, message} for an unknown key or a rule that can't be parsed. Takes the same
options as new!/2.

          @spec explain(t() | [t()], String.t(), keyword()) :: WardrikPolicy.Decision.t()


      


Decides a call like decide/3, but returns a WardrikPolicy.Decision that says what decided.
Given a list of policies, the strictest decision wins. If any policy denies the call, it's
denied. Otherwise, if any asks, it asks.

          @spec new!(keyword() | map(), keyword()) :: t()


      


Builds a policy from a keyword list or map. See the module docs for the keys.
WardrikPolicy.new!([deny: ["shell/*"], budget: [usd: 5.00]], name: "acme")
Raises ArgumentError with the message decode/2 would return if a rule, budget or judge
can't be read.
Options
	:name - names the policy in each WardrikPolicy.Decision. nil unless set.

          @spec to_json(t()) :: map()


      


Encodes a policy as the map decode/2 reads, such as to store it as JSON.
Leaves out what the policy doesn't set. The policy's :name is not part of it.

The question a person answers before a call can run. WardrikPolicy.Middleware parks on it.
	:interrupt - "tool_approval" or "model_approval".
	:message - the prompt for the person.
	:labels - labels for what the run had read, which may be what asked for the call.

          @type t() :: %WardrikPolicy.Ask{
  interrupt: String.t(),
  labels: [String.t()],
  message: String.t()
}

Caps what an agent spends on model calls, in dollars, tokens or both.
iex> policy = WardrikPolicy.new!(budget: [usd: 5.00, per: :day])
iex> WardrikPolicy.Budget.check(policy.budget, %{usd: 4.10})
:allow
iex> WardrikPolicy.Budget.check(policy.budget, %{usd: 5.02})
{:ask, "This agent has spent $5.02 of $5.00 today. Approve to allow $5.00 more."}
Call check/3 before each model call, with what the earlier calls spent. The call that crosses
the limit still runs. The next one asks. grant/2 records an approval and allows another
grant's worth:
iex> policy = WardrikPolicy.new!(budget: [tokens: 200_000, grant: [tokens: 50_000]])
iex> spent = WardrikPolicy.Budget.grant(policy.budget, %{tokens: 201_000})
iex> WardrikPolicy.Budget.check(policy.budget, spent)
:allow
iex> WardrikPolicy.Budget.check(policy.budget, %{spent | tokens: 251_000})
{:ask, "This agent has used 251,000 of 251,000 tokens today. Approve to allow 50,000 more."}
cost/2 prices a call that reports no cost at the budget's price, in dollars per million
tokens:
iex> policy = WardrikPolicy.new!(budget: [usd: 5.00, price: [input: 0.60, output: 2.20]])
iex> WardrikPolicy.Budget.cost(policy.budget, %{input_tokens: 10_000, output_tokens: 2_000})
0.0104
What was spent is a map with :usd, :tokens and :granted. A missing key counts as zero.
Reset it when period/2 returns a new period. WardrikPolicy.Middleware does all of this for you.
Options
	:usd - the limit in US dollars. No dollar limit unless set.
	:tokens - the limit in tokens, input and output together. No token limit unless set.
	:per - :turn, :day, :week, :month or :total. :day unless set.
	:timezone - where a day, week or month begins, as "Europe/Berlin". "Etc/UTC" unless set.
Weeks begin on Monday.
	:grant - how much more an approval allows, as [usd: 2.00]. Another limit's worth unless set.
	:price - dollars per million tokens, as [input: 0.60, output: 2.20]. Used for calls that
report no cost.
	:on_exhausted - :ask a person, or :deny. :ask unless set.

        A budget. See the module docs for its fields.

        check(budget, spent, opts \\ [])

      


        Checks what was spent against the budget.



    


    
      
        cost(budget, usage)

      


        Returns what a call cost in dollars.



    


    
      
        decode(fields)

      


        Reads a budget from a map with string keys, such as one parsed from YAML.



    


    
      
        grant(budget, spent)

      


        Records an approval. Each limit already reached allows another :grant's worth on top of what
was spent.



    


    
      
        period(budget, now)

      


        Returns the period now falls in. Reset what was spent when it changes.



    


    
      
        to_json(budget)

      


        Encodes a budget as the map decode/1 reads. Leaves out what the budget doesn't set.

          @type period() :: :turn | :total | {:day | :week | :month, Date.t()}

          @type spent() :: %{
  optional(:usd) => number(),
  optional(:tokens) => non_neg_integer(),
  optional(:granted) => %{
    optional(:usd) => number(),
    optional(:tokens) => integer()
  },
  optional(atom()) => term()
}

          @type t() :: %WardrikPolicy.Budget{
  grant: keyword(number()),
  on_exhausted: :ask | :deny,
  per: :turn | :day | :week | :month | :total,
  price: [input: number(), output: number()] | nil,
  timezone: String.t(),
  tokens: pos_integer() | nil,
  usd: number() | nil
}


      


A budget. See the module docs for its fields.

          @spec check(t(), spent(), keyword()) :: WardrikPolicy.decision()


      


Checks what was spent against the budget.
Returns :allow while under every limit. Otherwise returns {:ask, prompt} or
{:deny, message}, as :on_exhausted says.
iex> policy = WardrikPolicy.new!(budget: [usd: 5.00, on_exhausted: :deny])
iex> WardrikPolicy.Budget.check(policy.budget, %{usd: 5.02}, spender: "acme's agents have")
{:deny, "acme's agents have spent $5.02 of $5.00 today."}
Options
	:spender - who spent it, at the start of the message. "This agent has" unless set.

          @spec cost(t(), map()) :: number() | nil


      


Returns what a call cost in dollars.
Uses the call's own :usd when it has one. Otherwise prices its :input_tokens and
:output_tokens at the budget's :price. Returns nil when the budget has no price.

          @spec decode(map()) :: {:ok, t()} | {:error, String.t()}


      


Reads a budget from a map with string keys, such as one parsed from YAML.

          @spec grant(t(), spent()) :: spent()


      


Records an approval. Each limit already reached allows another :grant's worth on top of what
was spent.

          @spec period(t(), DateTime.t()) :: period()


      


Returns the period now falls in. Reset what was spent when it changes.
Returns :turn for a :turn budget, so reset it at each turn yourself. Raises ArgumentError
if :timezone isn't a time zone.

  



  
    
      
    
    
      to_json(budget)



    

  


  

      

          @spec to_json(t()) :: map()


      


Encodes a budget as the map decode/1 reads. Leaves out what the budget doesn't set.

What a policy decided about a call, and why. Returned by WardrikPolicy.explain/3.
	:effect - :allow, :ask or :deny.
	:message - the prompt or refusal. nil for an allow.
	:rule - the rule that decided, when :cause is :rule or :label.
	:policy - the name of the policy that decided, if it has one.
	:cause - what decided. See below.
	:measurements - what a judge's model call used.

The :cause is one of:
	:rule - a rule named the call.
	:no_rule - no rule covered the whole call, so default decided.
	:judge - the policy's judge decided.
	:budget - a model call reached the policy's budget.
	:label - a rule allowed a gated call, but the run had read labelled content.

        Returns the strictest decision. A deny beats an ask, and an ask beats an allow.

        Ranks an effect: 0 for :deny, 1 for :ask, 2 for :allow.

          @type t() :: %WardrikPolicy.Decision{
  cause: :rule | :no_rule | :judge | :budget | :label,
  effect: :allow | :ask | :deny,
  measurements: %{optional(term()) => number()},
  message: String.t() | nil,
  policy: String.t() | nil,
  rule: String.t() | nil
}


      



  


        

      

      
        Functions


        


  
    
      
    
    
      strictest(decisions)



    

  


  

      

          @spec strictest([t()]) :: t()


      


Returns the strictest decision. A deny beats an ask, and an ask beats an allow.
On a tie, a decision from a rule or judge beats one from a default. An empty list allows. The
result carries the summed measurements of all of them.

  



  
    
      
    
    
      strictness(atom)



    

  


  

      

          @spec strictness(:allow | :ask | :deny) :: 0..2


      


Ranks an effect: 0 for :deny, 1 for :ask, 2 for :allow.

  


        

      


  

    
WardrikPolicy.Judge 
    



      
Asks a model yes-or-no questions about each tool call, and decides by the probability of yes.
iex> policy =
...>   WardrikPolicy.new!(
...>     judge: [
...>       questions: [
...>         [
...>           question: "Does this call send money outside the company?",
...>           tools: ["books/*"],
...>           ask: 0.5,
...>           deny: 0.9
...>         ]
...>       ]
...>     ]
...>   )
iex> evaluate = fn _model, _state, _questions -> {:ok, [0.72], %{}} end
iex> WardrikPolicy.decide(policy, "books__pay_bill", evaluate: evaluate)
{:ask, "Judged 72% likely: Does this call send money outside the company?"}
Options
	:model - the model that answers. "typesafe:jev-latest" unless set.
	:questions - a list of questions, each with the keys below.

Each question takes:
	:question - required. What the model is asked about the call.
	:tools - tool names it applies to, as ["books/*"], without arguments. Every tool unless set.
	:deny - refuse the call at or above this probability.
	:ask - ask a person at or above this probability.
	:allow - allow the call below this probability.
	:message - the prompt or refusal to show in place of the question.

Each threshold is a probability from 0 to 1. A question needs at least one of them.
decode/1 returns an error otherwise.
Evaluating
A call's questions go to the model in one request, with the tool's name and arguments. Pass a
function as the :evaluate option of WardrikPolicy.decide/3 to make that request. See
evaluate/0. WardrikPolicy.Middleware uses WardrikCore.evaluate/4. What the request used
is returned in the decision's measurements.
How it combines with rules
	A deny beats an ask, and an ask beats an allow, across questions and rules.
	A judge's allow only decides calls no rule names. It never overrides a rule's ask or deny.
	A judge's allow is ignored once the run has read content from outside.
	If the model can't answer, the call asks a person, as long as some question could ask or deny.

The call's arguments may be written to fool the judge. Keep exact checks in rules, and test the
thresholds on real calls before trusting the judge's allow.

      


      
        Summary


  
    Types
  


    
      
        evaluate()

      


        Asks model each question about state. Returns each question's probability of yes, in order,
and what the request used.



    


    
      
        question()

      


    


    
      
        t()

      


    





  
    Functions
  


    
      
        decide(judge, name, arguments, evaluate)

      


        Decides a call to the tool name by the judge alone.



    


    
      
        decode(fields)

      


        Reads a judge from a map with string keys, such as one parsed from YAML.



    


    
      
        to_json(judge)

      


        Encodes a judge as the map decode/1 reads.



    





      


      
        Types


        


  
    
      
    
    
      evaluate()



    

  


  

      

          @type evaluate() :: (model :: String.t(), state :: map(), questions :: [String.t()] ->
                 {:ok, [float()], measurements :: map()} | {:error, term()})


      


Asks model each question about state. Returns each question's probability of yes, in order,
and what the request used.

  



  
    
      
    
    
      question()



    

  


  

      

          @type question() :: %{
  :question => String.t(),
  optional(:tools) => [String.t()],
  optional(:deny) => float(),
  optional(:ask) => float(),
  optional(:allow) => float(),
  optional(:message) => String.t()
}


      



  



  
    
      
    
    
      t()



    

  


  

      

          @type t() :: %WardrikPolicy.Judge{
  model: String.t(),
  questions: [question() | keyword()]
}


      



  


        

      

      
        Functions


        


  
    
      
    
    
      decide(judge, name, arguments, evaluate)



    

  


  

      

          @spec decide(t(), String.t(), map(), evaluate() | nil) ::
  WardrikPolicy.decision() | :pass


      


Decides a call to the tool name by the judge alone.
Returns :allow, {:ask, prompt} or {:deny, message}. Returns :pass when no question applies
or none crosses its threshold.

  



  
    
      
    
    
      decode(fields)



    

  


  

      

          @spec decode(map()) :: {:ok, t()} | {:error, String.t()}


      


Reads a judge from a map with string keys, such as one parsed from YAML.

  



  
    
      
    
    
      to_json(judge)



    

  


  

      

          @spec to_json(t()) :: map()


      


Encodes a judge as the map decode/1 reads.

  


        

      


  

    
WardrikPolicy.Middleware 
    



      
A WardrikCore.Middleware that holds an agent to one or more policies.
middleware: [{WardrikPolicy.Middleware, WardrikPolicy.new!(deny: ["shell/*"])}]
Pass a list to hold an agent to several policies, such as its org's and its own:
middleware: [{WardrikPolicy.Middleware, [org_policy, agent_policy]}]
For each tool call, it decides by the rules and judge before the call runs. A judge asks its
model with WardrikCore.evaluate/4. A refused call returns the refusal as its error, so the
model can carry on.
For each model call, it checks the budgets before the call and counts the cost after.
What was spent is kept in the context's private data, so it survives restarts.
Answering an ask
A call that asks parks on a WardrikPolicy.Ask. Answer it with WardrikCore.resume/2, keyed
by the tool call's id, or "model" for a model call:
WardrikCore.resume(agent, %{"call_123" => :approve})
WardrikCore.resume(agent, %{"call_123" => {:approve, "Checked with finance."}})
WardrikCore.resume(agent, %{"model" => {:deny, "Over budget for today."}})
A note reaches the model beside the call's result. A reason reaches it as the call's error.
Pass %{by: who} as WardrikCore.resume/3's metadata to record who answered.
A call parked :in_doubt, because it may already have run, takes the answer given for that.
The person isn't asked twice.
Events
Each decision is set on the step's span as the "wardrik.policy.decision" attribute. See
WardrikCore.Context.attribute/3.
These events go through WardrikCore.Event, so they reach the agent's events sink and
:telemetry:
	[:wardrik_policy, :decision] - every decision.
	[:wardrik_policy, :answer] - every answer. Carries the metadata given to
WardrikCore.resume/3.
	[:wardrik, :tool_call, :denied] - a tool call refused by a policy or a person.
	[:wardrik, :interrupt, :resolved] - an ask answered.

The first two carry agent_id, the step's span, the call (nil for a model call) and the
run's labels. See WardrikCore.Context.labels/1.

